Basic Pump Sizing using Bernoulli’s Principle in Scilab

Topic: Bernoulli’s Principle and Pump Sizing

Subject: Fluid Mechanics

Tool: Scilab

By: Gani Comia, Dec. 2024

The size of the pump for the particular application is decided base on the volumetric flow (\(Q\)) and the total dynamic head (\(TDH\)). The pump’s motor drive and specification in terms of \(HP\) can be just determined from the pump maker’s catalogue for the given flow rate and \(TDH\).

Consider an example wherein a centrifugal pump is needed for fire protection applications. Let us say that for the fire protection system, the following are being required:

Volumetric Flow, \(Q\) = 23 \(m^3/hr\) (100 \(GPM\) approx.)

Pressure, \(P\) = 300 ~ 700 \(kPa\) (50~100 \(psi\) approx.)

Volumetric flow is usually an available information based on application. The \(TDH\) is calculated considering the following factors:

1. Pressure Head
2. Static or Elevation Head
3. Velocity Head
4. Friction Head

For this presentation, the calculation of \(TDH\) will be based on the first three factors of Bernoulli’s Principle. The theoretical \(TDH\) can be adjusted by adding the total friction head and other factors.

Bernoulli’s principle is a fundamental concept in fluid dynamics that describes the relationship of pressure, elevation, and velocity of a fluid flow. It calculates the Total Dynamic Head (\(TDH\)) in pump systems. \(TDH\) is the total energy imparted by the pump to the fluid and calculated as shown:

$$TDH\;=\;H_p\;+\;H_z\;+\;H_v \tag{1}$$

For incompressible fluids, TDH can be expressed in the simplified form of Bernoulli’s equation:

$$TDH\;=\;\frac{P}{\gamma}\;+\;Z\;+\;\frac{v^2}{2g} \tag{2}$$

Fig. 1 shown a graph for the relationship of pressure and \(TDH\) for a given volumetric flow and different static or elevation heads. It can be a helpful guide for a pump designer to make a decision understandable to the stakeholders or clients. This also eliminates the impression of unjustifiable guesswork.

Fig. 1. Pump Sizing in terms of \(TDH\) based on pressure, static, and velocity head.

Presented here is the Scilab script as a toolbox to produce a similar graph for pump sizing using Bernoulli’s principle.

// Copyright (C) 2024 - Gani Comia
// Date of creation: 16 Dec 2024
// Water Pump Sizing using Bernoulli's Principle (Theory)
clear;clc;
// Pumps for fire protection
// Required Pressure = 138~1034 kPa (20~150 psi)
// Volumetric Flow = 22.7 m^3/hr (100 GPM)
// Required: Pump's TDH

// sub-routine program—total dynamic head
function H=tdh(P, z, V)
    wDensity = 9800;        // N/m^3, weight density of water
    g = 9.8;                // m/s^2, gravitational acceleration
    // P - kPa, pressure
    // z - m, elevation
    // V - m/s, velocity
    H = (1000*P)./wDensity + z + (V.^2)./(2*g)
endfunction

// main program
// (1) velocity head, calculation
Q = 23;                     // m^3/hr, volumetric flow rate
Q = Q/3600;                 // m^3/s, volumetric flow rate
// pipe size at service point dia 38mm GI Pipe S40
pipeID = (38-2*1.5)/1000;    // m, inside diameter of pipe
A = (%pi/4)*(pipeID.^2);     // m^2, pipe ID area
V = Q./A;                   // m/sec, velocity

// (2) elevation head, assume a range for simulation
z = 0:10:50;                // m, elevation range
Nz = length(z)              // no. of elevation steps
disp(z)

// (3) pressure head, assigned a domain for simulation
// P = 300 ~ 700 kPa pressure range
P = linspace(300,700,Nz);   // kPa, pressure range

// (4) simulation plot
clf;
for i = 1:Nz
    H = tdh(P,z(i),V)
    plot(P,H,"linewidth",1.75)
    title("H2O Pump Sizing using the Bernoulli Principle")
    xlabel("Pressure, P [ kPa ]")
    ylabel("Total Dynamic Head, TDH [ m ]")
end

P1 = 600;
for i = 1:Nz
    H1 = tdh(P1,z(i),V)
    note1 = ["Z =",string(z(i)),"m"]
    xstring(P1,H1,note1,-18)
end

// (5) simulation of sample parameters
// for elevation = 20 m and pressure = 500 kPa
P2 = 500;                                   // kPa, sample pressure
H2 = tdh(P2,z(3),V);                        // m, sample tdh
x1 = [P2 P2];
y1 = [30 H2];
plot(x1,y1,"--r")                           // vertical line
xstring(P2,32,["P =",string(P2)],-90)
x2 = [300 P2];
y2 = [H2 H2];
plot(x2,y2,"--r")                           // horizontal line
format(6);
xstring(350,H2,["TDH =",string(H2)])
plot(P2,H2,"o","color","black")
note2 = ["Q =",string(3600*Q),"m3 / hr"]
xstring(350,120,note2)
note3 = ["https://gani-mech-toolbox.blogspot.com"]
xstring(350,115,note3)

// custom markers 
a = gca();
a.children.children.mark_background = 9;    // Fill color

This kind of pump sizing or selection can simplify the intricacies of engineering analysis, especially for the stakeholders with minimal or no knowledge at all in fluid mechanics.

Feel free to comment for inquiry, clarification, or suggestion for improvement. Drop your email to request the soft copy of the file.

Disclaimer: The formulas and calculations presented are for technical reference only. Users must verify the accuracy and ensure compliance with applicable engineering standards, codes, and safety requirements before practical application. 

Temperature Data Extraction, Visualization and Analysis using Scilab

Topic: Numerical Analysis of Temperature from Data Acquisition System (DAS);

Subject: Heat Transfer;

Tool: Scilab;

By: Gani Comia, Dec. 2024;

Data acquisition devices or systems record process data over time for monitoring and analysis purposes. This article presented how the Scilab software extracts, visualizes, and analyzes temperature numerical data from a DAS.

While DAS can actually show a graph of the data in real-time, other analysis can only be done after downloading the data soft copy in .CSV format. This blog post presented the two analyses made with the use of Scilab scripting. The first analysis made was to find the specific time for a particular temperature value, and the second one was the calculation of heat rate, or the temperature change per unit time during ramp-up.

The completed plot or graph of numerical data using Scilab is shown.

Fig. 1. Scilab Plot and Analysis of Temperature Data.

Below are the code snippets or scripts for the two sample analyses made. The completed script is shown after.

Analysis (1): Finding the Time for Specific Temperature.

// ----- analysis(1) : finding time @ temp = 232 degC -----
modOvenWallTemp = round(ovenWallTemp);
id = find(modOvenWallTemp >= 232,[-1]);  // max no. of indices
timeStd(1) = time(id(1));
timeStd(2) = time(id($));

Analysis (2): Temperature per Unit Time during Ramping-up.

// ----- analysis(2) : finding heat rate in degC / min -----
tempCond = [ovenWallTemp(1) temp(2)];
timeCond = [time(1) timeStd(1)];
heatRate = diff(tempCond)./diff(timeCond);

Scilab Script (Complete):

// Copyright (C) 2024 - Gani Comia
// Date of creation: 4 Dec 2024
// Heating Oven Temperature Data Analysis using Scilab
clear;clc;
// data extraction
clear importdata;

function [data]=importdata(filename)
    data = csvRead(filename, ",", ".", "double")
endfunction

[A] = importdata("temp_profile_before_repair_xform.csv");

// assigning data to the variables
time = A(2:$,13);
ovenWallTemp = A(2:$,2);
partTemp = A(2:$,9);

// data visualization
clf;
f=gcf();
f.figure_size=[900,600];
plot(time,ovenWallTemp,"-b","linewidth",1.75)
plot(time,partTemp,"-.r","linewidth",1)
legend(["Oven Wall","Workpiece"],"in_upper_right")
title("Analysis of Oven Temperature Profile from Data Logger")
xlabel("Time [ min ]")
ylabel("Temperature [ deg C ]")
xstring(245,100,"https://gani-mech-toolbox.blogspot.com")
a=gca(); 
a.data_bounds = [0 0;400 300]; 

// additional plot properties
t = [0:60:360, 400];
temp = [0 232 300];

// temp = 232 degC horizontal lines
plot([t(1),t($)],[temp(2),temp(2)],"--g","linewidth",1)
xstring(5,232,"Std = 232 C")

// hourly verical lines
for i = 2:length(t)-1
    plot([t(i),t(i)],[temp(1),temp(3)],"--y","linewidth",1)
end

// hourly label 
minute = 60;
hour = 1;
for i = 2:length(t)-1
    note = [string(hour),"hour"];
    xstring(minute,10,note,-90);
    minute = minute + 60;
    hour = hour + 1;
end

// ----- analysis(1) : finding time @ temp = 232 degC -----
modOvenWallTemp = round(ovenWallTemp);
id = find(modOvenWallTemp >= 232,[-1]);  // max no. of indices
timeStd(1) = time(id(1));
timeStd(2) = time(id($));

// plot of analysis(1)
timeStd = [timeStd(1) timeStd(2)];
stdTemp = [232 232];
plot(timeStd, stdTemp, "ro")
xstring(timeStd(1),stdTemp(1)-15,[string(timeStd(1)),"min"])
xstring(timeStd(2),stdTemp(2),[string(timeStd(2)),"min"])
ambient = ["Ini =",string(round(ovenWallTemp(1))),"C"];
xstring(0,ovenWallTemp(1)-15,ambient)

// ----- analysis(2) : finding heat rate in degC / min -----
tempCond = [ovenWallTemp(1) temp(2)];
timeCond = [time(1) timeStd(1)];
heatRate = diff(tempCond)./diff(timeCond);

// plot of analysis(2)
plot(timeCond,tempCond,"--","color","dimgray","linewidth",2)
noteHR = ["RATE:",string(round(heatRate)),"deg C / min"]
xstring(t(2)-20,110,noteHR,-58)

A readily available program script with some minor revision can facilitate visualization and analysis of numerical data for almost similar conditions. Program or code reusability leading to short lead times of engineering analysis is one of the benefits of using a programming tools in the engineering field.

Feel free to comment for inquiry, clarification, or suggestion for improvement. Drop your email to request the soft copy of the file.

Disclaimer: The formulas and calculations presented are for technical reference only. Users must verify the accuracy and ensure compliance with applicable engineering standards, codes, and safety requirements before practical application.

Steady-State Heat Conduction Model using FDM Solution to 2D Laplace Equation

Topic: Finite Difference Method of Laplace Equation in 2D;

Subject: Heat Transfer and Numerical Methods;

Tool: Scilab;

By: Gani Comia, Dec. 2024;

The steady-state heat conduction model can be represented mathematically by Laplace equation. Shown is the Laplace equation in 2D:

$$\frac{\partial^2 T}{\partial x^2}+\frac{\partial^2 T}{\partial y^2}\;=\;0$$

The solution, \(T(x,y)\), represents the temperature distribution. The Laplace equation can be discretized using the Finite Difference Method (FDM) to approximate the solution numerically. This article will present the Scilab script of the FDM solution to the Laplace equation.

The FDM solution for a uniform grid, \((\Delta x = \Delta y)\), with the boundary temperatures specified based on Dirichlet conditions, is shown:

$$T_{i,j}\;=\;\frac{T_{i+1,j}+T_{i-1,j}+T_{i,j+1}+T_{i,j-1}}{4}$$

The final value of  \(T(x,y)\) is the result of iteration based on the convergence criterion:

$$max\left\vert T_{i,j}^{new}\;-\;T_{i,j}^{old}\right\vert\;<\;\epsilon$$

Consider a sample 2D domain of dimensions 30x30 units with the following constant temperature conditions. 

Fig. 1. Sample 2D Domain with Constant Temperature.

Shown below is the temperature profile as represented by \(T(x,y)\) using the FDM solution to the Laplace equation.

Fig. 2. Temperature Profile \(T(x,y)\).

The Scilab script as a toolbox can be used to implement the FDM numerical solution for the steady-state heat conduction model represented mathematically using the Laplace equation.

Scilab Script

// Copyright (C) 2024 - Gani Comia
// Date of creation: 8 Dec 2024
// FDM Solution to 2D Laplace Eq, d2T/dx2 + d2T/dy2 = 0
clear;clc;
// domain and grid parameters
Lx = 30;                    // units, domain length at x-axis
Ly = 30;                    // units, domain length at y-axis
dx = 1;                     // grid spacing at x-axis
dy = 1;                     // grid spacing at y-axis
nx = Lx./dx;                // no. of grid points in x-direction
ny = Ly./dy;                // no. of grid points in y-direction
max_iter = 1000;            // max no. of iterations
tolerance = 1e-6;           // convergence tol.

// temperature field initial value
T = zeros(nx, ny);
// boundary value conditions
    T(:,1) = 0;             // T = 0 C @ y = 1
T(1,:) = 0;                 // T = 0 C @ x = 1
T(:,ny) = 0;                // T = 0 deg C @ y = 30
T(nx,:) = 100;              // T = 100 deg C @ x = 30

// finite difference method (Jacobi iteration)
for iter = 1:max_iter
    Tnew = T;
    for i = 2:nx-1
        for j = 2:ny-1
            Tnew(i,j)=0.25*(T(i+1,j)+T(i-1,j)+T(i,j+1)+T(i,j-1));
        end
    end
    // convergence check
    if norm(Tnew - T) < tolerance then
        break;
    end
    T = Tnew;
end
// calculation status 
mprintf("\n\tCalculation completed!\n")

// plot properties
clf;
f = gcf()
f.figure_size = [700,650]
ax = gca()
ax.tight_limits = ["on" "on" "off"];

// plotting results
surf(T);
title(["$Temperature\;Profile$","$T(x,y)$"],"fontsize",4);
xlabel("x-axis");
ylabel("y-axis");
zlabel("$T$");
colormap(jet);
colorbar(0,100);

Feel free to comment for inquiry, clarification, or suggestion for improvement. Drop your email to request the soft copy of the file.

Disclaimer: The formulas and calculations presented are for technical reference only. Users must verify the accuracy and ensure compliance with applicable engineering standards, codes, and safety requirements before practical application.